不少朋友问艾云策略有没有文华8的量化日内交易策略模型，我好几年没有用文华8了，以前收集了WH8量化日内交易的十一种经典入场模型分享给大家：
1.模型仅仅作为思路拓展，不建议直接实盘使用。依此入市，风险自负。
交易员们可以根据这些经典的策略进行改编，结合平时的交易经验，形成自己的交易策略。
2. 以下经典策略均来自于网络，是根据网络中常见的方式改写的。
RANGE BREAK
波动区间突破交易，根据昨天波动幅度的一定百分比，来触发当日的趋势交易，如果昨天的波动幅度是异常的，应当对该波动幅度进行必要的调整，以保持合理性。
策略原理：
RangeBreak区间突破交易系统,区间的上下轨根据前一个交易的振幅决定
区间上下轨的确定：
昨日振幅=昨日最高价-昨日最低价;
今日行情区间上轨=今日开盘价+N*昨日振幅;
今日行情区间下轨=今日开盘价-N*昨日振幅;
其中变量N的取值范围较为灵活,可以依据交易品种的波动属性和个人交易经验进行变换。通常情况下,N的取值范围位于0.5-0.8之间。
买卖信号：
1、突破上轨,买入开仓做多;
2、突破下轨,卖出开仓做空;
策略源码：
N:=0.5;//通常,N的取值范围位于0.5-0.8之间,也可根据经验定义
ZH:=REF(HHV(H,DAYBARPOS),DAYBARPOS);//昨日最高价
ZL:=REF(LLV(L,DAYBARPOS),DAYBARPOS);//昨日最低价
ZF:=ZH-ZL;//昨日振幅
JO:=REF(O,DAYBARPOS-1);//今日开盘价
SG:JO+N*ZF;//上轨
XG:JO-N*ZF;//下轨
C>SG,BPK;
C<XG,SPK;
AUTOFILTER;
艾云指标—白金版
菲阿里四价
昨天高点，昨天低点，昨天收盘，今天开盘，可并称为菲阿里四价，它是由日本期货冠军菲阿里实盘采用的主要突破交易的参照系，此外，因菲阿里主观心智交易的模式，决定了其在实际交易中，还大量结合应用了“阻溢线”的概念，即我们通常所说的压力、支撑线。
策略原理：
依据昨日高点、昨日低点、昨日收盘、今日开盘确定开闭盘条件
1、趋势交易策略
上下轨确定：
上轨＝昨日高点；
下轨＝昨日低点；
买卖信号：
1、当价格突破上轨，买入开仓；
2、当价格跌穿下轨，卖出开仓。
策略源码：
NN1:=BARSLAST(DATE<>REF(DATE,1))+1;
NNC1:=COUNTSIG(BK,NN1)+COUNTSIG(SK,NN1)+COUNTSIG(BPK,NN1)+COUNTSIG(SPK,NN1);
//表示当日的开仓次数
ZG:REF(HHV(H,NN1),NN1);
ZD:REF(LLV(L,NN1),NN1);//分别表示昨日最高价格 昨日最低价格
CROSSUP(C,ZG)&&NNC1<5,BK;
CROSSDOWN(C,ZD)&&NNC1<5,SK;
//表示突破昨日最高价做多 突破昨日最低价格做空(当日做多做空最大5次)
C<=BKPRICE-10*MINPRICE,SP;
C>=SKPRICE+10*MINPRICE,BP;//表示开仓价格的10个点位止损平仓
C>=BKPRICE+40*MINPRICE,SP;
C<=SKPRICE-40*MINPRICE,BP;//表示开仓价格的40点止盈
ISLASTKLINE,CLOSEOUT;//尾盘清仓
AUTOFILTER;
2、震荡交易策略
买卖信号：
开盘下跌，今日开盘价<昨日收盘价，当价格突破开盘价时，做多。
开盘上涨，今日开盘价>昨日收盘价，当价格跌破收盘价时，做空；
策略源码：
NN1:=BARSLAST(DATE<>REF(DATE,1))+1;
NNC1:=COUNTSIG(BK,NN1)+COUNTSIG(SK,NN1)+COUNTSIG(BPK,NN1)+COUNTSIG(SPK,NN1);
//表示当日的开仓次数
ZC:REF(C,NN1);//昨日收盘价
JK:VALUEWHEN(NN1=1,O);//今日开盘价
JK<ZC&&CROSSUP(C,JK)&&NNC1<5,BK;
JK>ZC&&CROSSDOWN(C,ZC)&&NNC1<5,SK;
//开盘下跌,价格突破开盘价时做多 ; 开盘上涨,价格跌破收盘价时做空(当日做多做空最大5次)
C<=BKPRICE-10*MINPRICE,SP;
C>=SKPRICE+10*MINPRICE,BP;//表示开仓价格的10个点位止损平仓
C>=BKPRICE+40*MINPRICE,SP;
C<=SKPRICE-40*MINPRICE,BP;//表示开仓价格的40点止盈
ISLASTKLINE,CLOSEOUT;//尾盘清仓
AUTOFILTER;
空中花园
开盘突破，是最快的一种入场方式，当然出错的概率也最高，开盘第一根K线是收阳，还是收阴，是判断日内趋势可能运动方向的标准，我们发现这种入场在当天开盘高开或低开时更为有效。在《期市截拳道》中，把这种交易策略称为“空中花园”，西蒙斯在早期也曾经应用过类似的交易策略。
策略原理：
空中花园 着重开盘突破的交易模式，开盘时的高开或者低开，均说明有大的利好或者利空，使得开盘大幅远离昨天的收盘价。具体交易原则如下：
区间上下轨的确定：
当开盘价>=昨天收盘价*1.01 或开盘价<=昨天收盘价*0.99
上轨＝第一根K线的最高价；
下轨＝第一根K线的最低价；
当价格突破上轨，买入开仓；当价格跌穿下轨，卖出开仓；当日收盘平仓
策略源码：
NN:=BARSLAST(DATE<>REF(DATE,1))+1;//表示当日的K线根数
SG:REF(H,NN-1);//上轨＝第一根K线的最高价；
XG:REF(L,NN-1);//下轨＝第一根K线的最低价；
TJ:C>=REF(C,1)*1.01||C<=REF(C,1)*0.99;//当开盘价>=昨天收盘价*1.01或开盘价<=昨天收盘价*0.99时；
REF(TJ,NN-1)&&CROSS(C,SG),BPK;//当价格突破上轨，买入开仓；
REF(TJ,NN-1)&&CROSSDOWN(C,XG),SPK;//当价格跌穿下轨，卖出开仓。
AUTOFILTER;
横盘突破
较易于实现量化的形态突破，有分型，窄幅横盘突破，各种K线组合、双顶、双底、缠论三买三卖等，较难于实现量化的形态突破，有趋势线、圆孤顶底、旗型、菱形、三角形等各种经典技术分析形态，趋势之后是盘整，盘整之后是趋势，横盘突破的交易策略，充分体现了波动性循环的价格波动规律，我们需要做的事情就是合理量化盘整的定义：周期跨度、波动幅度。
策略原理：
横盘，是指股价在一段时间内波动幅度小，无明显的上涨或下降趋势，行情震幅小，方向不易把握。
上下轨的确定：
在过去30根K线的高低点围绕中轴上下0.5%的范围内波动时；
上轨＝过去30根K线的最高价；
下轨＝过去30根K线的最低价；
买卖信号：
1、价格突破上轨，买入开仓；
2、价格跌穿下轨，卖出开仓。
策略源码：
N1:=0.005;
CYC:=BARSLAST(DATE<>REF(DATE,1))+1;//记录K线的个数，即交易日数
H30:REF(HHV(H,30),1);
L30:REF(LLV(L,30),1);
MID:(H30+L30)/2;//中轴
开多条件:= H>H30 AND (H30-MID)/MID<N1 AND CYC>=30 ;
开空条件:= L<L30 AND (MID-L30)/MID<N1 AND CYC>=30 ;
开多条件,BPK;
开空条件,SPK;
AUTOFILTER;
基于固定百分比幅度的转向交易
该系统曾在某交易系统策略大赛中荣获第二名的殊荣，也是大多数最为衷情的日内突破交易策略。相对而言，基于固定点位的突破，可能会受制于品种价格区域的变化而变迁，而基于固定百分比幅度的突破，则较少受到类似的困扰，除非该品种的波动性水平发生巨变。
策略原理：
转向交易，转向交易基于今日开盘价；
区间上下轨的确定：
上轨＝今日开盘价+今日开盘价*0.01；
下轨＝今日开盘价－今日开盘价*0.01；
买卖信号：
当价格突破上轨，买入开仓；
当价格跌穿下轨，卖出开仓。
策略源码：
OO:VALUEWHEN(DAYBARPOS=1,O);
HH:OO+OO*0.01;
LL:OO-OO*0.01;
CROSSUP(C,HH),BPK;
CROSSDOWN(C,LL),SPK;
AUTOFILTER;
HANS123
作为外汇市场上广为流传的一种突破交易策略，HANS123 以其简捷的开盘后N根K线（分钟）的高低点突破，作为交易信号触发的评判标准。这也是一种入场较早的交易模式，配套价格包括带、时间确认、波动幅度要求等项过滤技术、或可提高其胜算。
策略原理：
过滤掉隔夜信息后进行交易，当有些突发信息公布，市场分歧很大的时候，开盘会呈现方向不明、宽幅震荡的情况，此时，对任何突破策略都会是灾难，所以忽略这段时间。
区间上下轨的确定：
上轨＝开盘后30分钟高点；
下轨＝开盘后30分钟低点；
买卖信号：
当价格突破上轨，买入开仓；
当价格跌穿下轨，卖出开仓。
策略源码：
N:=BARSLAST(DATE<>REF(DATE,1))+1;
上轨:=VALUEWHEN(CROSS(TIME>=0930&&TIME<1500,0.5),HHV(H,N));//开盘30分钟最高价
下轨:=VALUEWHEN(CROSS(TIME>=0930&&TIME<1500,0.5),LLV(L,N));//开盘30分钟最低价
开多条件:=CROSS(C,上轨);
开空条件:=CROSSDOWN(C,下轨);
开多条件&&(TIME<1410||TIME>2100),BPK;
开空条件&&(TIME<1410||TIME>2100),SPK;
AUTOFILTER;
日均ATR波动性突破
我们有理由相信，当一定幅度的ATR波动性幅度已经发生，我们将更愿意去赌日内波动的方向朝着这个已经完成一定幅度ATR的方向继续发展，比较的基准，可以是开盘价，也可以是日内创下的新高、新低记录位置。
策略原理：
当一定幅度的ATR波动性幅度已经发生，大概率下，日内波动方向朝着这个已经完成一定ATR幅度的方向继续发展，可以是开盘价，也可以是日内已经创下的新高、新低记录位置
区间上下轨的确定：
日均ATR突破基于今日开盘价与过去N个交易日平均ATR的关系；
上轨＝今日开盘价+N个交易日平均ATR*M；
下轨＝今日开盘价－N个交易日平均ATR*M；
买卖信号：
1、突破上轨,买入开仓做多;
2、突破下轨,卖出开仓做空;
策略源码：
N:=26;//简单定义26周期的ATR
TR : =MAX(MAX((HIGH-LOW),ABS(REF(CLOSE,1)-HIGH)),ABS(REF(CLOSE,1)-LOW));
ATR : =MA(TR,N),COLORYELLOW;//求N个周期内的TR的简单移动平均
M:=1/2;//简单定义M倍的ATR
SG:VALUEWHEN(DAYBARPOS=1,O)+M*ATR;
XG:VALUEWHEN(DAYBARPOS=1,O)-M*ATR;//表示当日K线的开盘价加减M倍的ATR为上下轨
CROSSUP(C,SG),BPK;
CROSSDOWN(C,XG),SPK;
AUTOFILTER;
ORB失败突破
ORB交易最早于1988年由美国基金经理托比提出，它通过衡量开盘价与最高价、最低价距离的取小者，为失败突破幅度，后市一旦超出这个幅度，就认为真正的突破。在实际应用过程中，早评的突破、窄幅波动日后的突破，可以作为有效的过滤条件。
策略原理：
ORB失败突破，判断开盘价与最高价、最低价距离的较小者，为失败突破幅度，后市一旦超过这个幅度，便认为是真正的突破。在实际应用中，早盘的突破、窄幅波动后的突破，可作为有效的过滤条件
区间上下轨的确定：
基于过去N个交易日ORB指标；
上轨＝今日开盘价+N天ORB*M；
下轨＝今日开盘价－N天ORB*M；
过去失败的次数多，下一次成功的概率就比较高，N通常取10。
买卖信号：
1、突破上轨,买入开仓做多;
2、突破下轨,卖出开仓做空;
策略源码：
N:=10;
M:=1.2;
NN:=DAYBARPOS;
DN:=HHV(NN,BARPOS);//当日的K线根数，适用于1min及以上周期使用
OO:=VALUEWHEN(NN=1,OPEN);//当日开盘价
HH:=HHV(HIGH,NN);//当日最高价
LL:=LLV(LOW,NN);//当日最低价
HT:=REF(HH,NN);//昨高
LT:=REF(LL,NN);//昨低
CT:=REF(C,NN);//昨收
ORB:=MIN(ABS(HT-CT),ABS(LT-CT));
DTN:=N*DN;//N日的K线根数
BAND:=VALUEWHEN(NN=1,MA(ORB*M,DTN));//N天ORB*M
SG:OO+BAND;//上轨
XG:OO-BAND;//下轨
CROSSUP(C,SG),BPK;
CROSSDOWN(C,XG),SPK;
AUTOFILTER;
分时均价黄线
分时均价黄线，因其广泛出现于各类交易软件的内置分时走势图中，因而，就交易策略的自我实现预言而论，它的地位格外突出，醒目。
策略原理：
分时均价黄线，根据开盘后十分钟价格与均线走势判断交易方向：
区间上下轨的确定：
1、在开盘10分钟后准备入场;
2、上轨＝当日分时均价黄线；
3、下轨＝当日分时均价黄线；
买卖信号：
1、突破上轨,买入开仓做多;
2、突破下轨,卖出开仓做空;
策略源码：
SS:SETTLE;//日内均价线
CROSSUP(C,SETTLE),BPK;
CROSSDOWN(C,SETTLE),SPK;//表示上穿日内均价线做多 下穿日内均价线做空
AUTOFILTER;
日内ATR波动性突破
与“日均ATR波动性突破”不同，“日内ATR波动性突破”更侧重于短期市场波动率的变化评估，波动性突破，在一定程度上具备适应市场的功能，在实际应用于适应不同市场环境的能力更强。
策略原理：
日内ATR突破基于当根K线开盘价与过去N个周期的ATR；
上轨＝当根K线开盘价 N周期ATR*M；
下轨＝当根K线开盘价－N周期ATR*M；
当价格突破上轨，买入开仓；
当价格跌穿下轨，卖出开仓。
策略源码：
N:=26;
TR : =MAX(MAX((HIGH-LOW),ABS(REF(CLOSE,1)-HIGH)),ABS(REF(CLOSE,1)-LOW));
ATR : =MA(TR,N),COLORYELLOW;
M:=1/2;//简单定义M倍的ATR
SG:O+M*ATR;
XG:O-M*ATR;//表示当根K线的开盘价加减M倍的ATR为上下轨
CROSSUP(C,SG),BPK;
CROSSDOWN(C,XG),SPK;
AUTOFILTER;
Dual Thrust
DualThrust策略由MichaelChalek 在20世纪80年代开发，曾被FutureThruth杂志评为最赚钱的策略之一。Dual Thrust策略是一种趋势跟踪系统，属于日内交易策略。具有简单易用和适用度广的特点，其思路简单、参数很少，可以配合不同的参数、止盈止损和仓位管理
策略原理：
利用前N日的最高价，最低价和收盘价，来确定一个合理的震荡区间Range。通过开盘价和Range，确定当前的上下双轨，如果当前价格向上（向下）突破Range一定的比例，则认为一波上涨（下跌）行情形成，产生买入（卖出）信号
区间上下轨的确定：
1、震荡区间=最大值（N日HIGH的最高价-日CLOSE的最低价，N日CLOSE的最低价-N日LOW的最低价）;
2、上轨＝今日开盘价+K1*震荡区间；
3、下轨＝今日开盘价-K2*震荡区间；
买卖信号：
1、突破上轨,买入开仓做多;
2、突破下轨,卖出开仓做空;
策略源码：
N:=4;
K1:=0.3;
K2:=0.3;
NN:=SUMBARS(DATE<>REF(DATE,1),N);
TN := BARSLAST(DATE <> REF(DATE, 1)) + 1;
HH:=HHV(H,NN);//N日HIGH的最高价
LC:=LLV(C,NN);//N日CLOSE的最低价
HC:=HHV(C,NN);//N日CLOSE的最高价
LL:=LLV(L,NN);//N日LOW的最低价
RANGEX:=MAX(HH-LC,HC-LL);//计算震荡区间RANGE
TODAYOPEN := VALUEWHEN(TN = 1, OPEN); //今日开盘价
BUYLINE:TODAYOPEN +K1*RANGEX;//上轨
SELLLINE:TODAYOPEN -K2*RANGEX;//下轨
C>BUYLINE,BPK;
C<SELLLINE,SPK;
ISLASTKLINE,CLOSEOUT;
AUTOFILTER;
十一种文华8量化日内交易入场模型的编写方式在针对不同的交易品种，需要细致地调整设置的参数，并采用与之相匹配的入场策略。
为了实现最佳的交易效果，艾云策略建议期货、恒指、外汇等交易员们应当充分结合自身丰富的交易经验，谨慎地选择适合的入场策略。这样的策略调整不仅有助于提升交易的精确性，还有助于降低潜在的风险。